One Hat Cyber Team

Your IP: 216.73.216.177
Server IP: 50.6.168.112
Server: Linux server-617809.webnetzimbabwe.com 5.14.0-570.25.1.el9_6.x86_64 #1 SMP PREEMPT_DYNAMIC Wed Jul 9 04:57:09 EDT 2025 x86_64
Server Software: Apache
PHP Version: 8.4.10
Buat File | Buat Folder

View File Name : geo_construct.t

#!perl

use strict;
use warnings;

use URI::geo;
use Test::More;
use Data::Dumper;

package Pointy;

sub new {
  my ( $class, $lat, $lon, $alt ) = @_;
  return bless { lat => $lat, lon => $lon, alt => $alt }, $class;
}

sub lat { shift->{lat} }
sub lon { shift->{lon} }
sub alt { shift->{alt} }

package Pointy::Point;

our @ISA = qw( Pointy );

sub latlong {
  my $self = shift;
  return $self->{lat}, $self->{lon};
}

package main;

my @case = (
  {
    name => 'Simple',
    args => [ 54.786989, -2.344214 ],
    lat  => 54.786989,
    lon  => -2.344214,
    alt  => undef,
  },
  {
    name => 'Simple w/ alt',
    args => [ 54.786989, -2.344214, 120 ],
    lat  => 54.786989,
    lon  => -2.344214,
    alt  => 120,
  },
  {
    name => 'Array',
    args => [ [ 54.786989, -2.344214 ] ],
    lat  => 54.786989,
    lon  => -2.344214,
    alt  => undef,
  },
  {
    name => 'Hash, short names',
    args => [ { lat => 54.786989, lon => -2.344214 } ],
    lat  => 54.786989,
    lon  => -2.344214,
    alt  => undef,
  },
  {
    name => 'Hash, long names',
    args => [
      {
        latitude  => 54.786989,
        longitude => -2.344214,
        elevation => 3
      }
    ],
    lat => 54.786989,
    lon => -2.344214,
    alt => 3,
  },
  {
    name => 'Point object',
    args => [ new Pointy( 54.786989, -2.344214, 3 ) ],
    lat  => 54.786989,
    lon  => -2.344214,
    alt  => 3,
  },
  {
    name => 'Point object',
    args => [ new Pointy::Point( 54.786989, -2.344214 ) ],
    lat  => 54.786989,
    lon  => -2.344214,
    alt  => undef,
  },
  {
    name => 'URI::geo object',
    args => [ new URI::geo( 54.786989, -2.344214, 99 ) ],
    lat  => 54.786989,
    lon  => -2.344214,
    alt  => 99,
  },
);

plan tests => @case * 5;

for my $case ( @case ) {
  my ( $name, $args, $lat, $lon, $alt )
   = @{$case}{ 'name', 'args', 'lat', 'lon', 'alt' };

  ok my $guri = URI::geo->new( @$args ), "$name: created";
  is $guri->scheme, 'geo', "$name: scheme";
  is $guri->latitude,  $lat, "$name: latitude";
  is $guri->longitude, $lon, "$name: longitude";
  is $guri->altitude,  $alt, "$name: altitude";
}

# vim:ts=2:sw=2:et:ft=perl